7  Corrélation d’images

On étudie dans ce TP un solide de forme cubique soumis à un effort de compression. Nous cherchons à déterminer :

Le champ de déplacement sera obtenu par des mesures de corrélation d’images numériques. En parallèle, un modèle du problème sera mis en place pour obtenir une approximation de ce champ par des calculs d’élasticité plane. Le dialogue entre essais et calculs permettra de proposer une valeur d’effort.

7.1 Principe de la corrélation d’images numériques

L’objectif de cette partie est d’acquérir des connaissances générales sur la technique étudiée. On pourra notamment s’aider du guide édité par la fédération iDICs.

  1. Expliquez brièvement le principe de cette technique. Pourquoi un marquage est-il appliqué sur la face du solide étudiée ? Quelle est la loi de conservation qui est mise en oeuvre pour obtenir le déplacement ?
  2. Est-il possible d’obtenir une valeur du déplacement en chaque pixel ? Donnez une estimation de la résolution sur les champs cinématiques à laquelle on peut s’attendre dans notre cas.
  3. Donnez deux avantages d’une mesure de corrélation d’images par rapport à l’utilisation d’un extensomètre.

7.2 Essai de compression

On utilisera le montage de TP en mode “compression”. Les calculs de corrélation d’images seront effectués via le module “DIC” du site Mecapix.

  1. Vérifiez que le taquet métallique est dans la position de référence. Prenez une image de l’échantillon dans ces conditions.
  2. Changez la position du taquet métallique de manière à comprimer l’échantillon. Prenez ensuite une image de l’échantillon comprimé.
  3. Importez les deux images dans Mecapix (module “Digital Image Correlation”, bouton “Upload”).
  4. On utilisera l’algorithme “pyxel”. On travaillera dans un premier temps avec une fenêtre de 15 pixels. Lancez un premier calcul de corrélation. A partir des résultats donnés par Mecapix, identifiez les directions principales de déformation. Sont-elles cohérentes avec le problème étudié ?
  5. Faites varier la taille de fenêtre entre 5 et 50 pixels. Commentez l’effet de ce choix sur la convergence de l’algorithme et sur les valeurs de \(\varepsilon_{yy}\) obtenues.

7.3 Premier modèle

Cube en compression

On considère le problème ci-dessous, étudié selon une hypothèse de déformations planes. Le bord PS est supposé appuyé (déplacement vertical nul), tandis que le bord QR est soumis à un effort de pression \(p\). L’origine du repère est prise en O. On prendra comme paramètres matériau :

\(E\) \(\rho\) \(\nu\)
0.2 MPa 100 kg/m³ 0.15
  1. Les hypothèses de modélisation sont-elles cohérentes vis-a-vis du solide étudié expérimentalement ? On se basera notamment sur la mesure de ses dimensions.
  2. Montrez que l’utilisation de la fonction d’Airy \(\phi(x,y) = -p \frac{x^2}{2}\) permet de satisfaire l’ensemble des conditions aux limites en effort.
  3. En déduire les composantes planes du tenseur des contraintes en tout point du solide.
  4. On utilise les conditions aux limites suivantes : \(u_x(O) = 0\), \(u_y(O)=0\) et \(u_x(O')=0\). Calculez les composantes \(u_1\) et \(u_2\) du champ de déplacement.
  5. Comparer l’allure du champ de déplacement obtenu avec celui mesuré expérimentalement. Commenter les éventuelles différences.
  6. En utilisant la valeur du maximum de la déformation \(\varepsilon_{yy}\), donnez une estimation de l’effort imposé \(p\).

7.4 Deuxième modèle

Pour palier certaines des limitations mises en avant dans la question 4 de la section précédente, on a recours à un calcul éléments finis 2D. Les simulations seront réalisées avec le code Cast3m. Un fichier d’input est proposé ci-dessous. Les calculs peuvent être lancés dans un terminal via la commande

castem25 nom_du_fichier.dgibi
  1. Vérifiez que le fichier proposé est cohérent avec le problème étudié. On pourra notamment ajuster la valeur des paramètres.
  2. Faites varier la finesse du maillage. Caractérisez la convergence de la valeur de \(\varepsilon_{yy}\) au centre du solide.
  3. Modifiez la valeur de la pression appliquée jusqu’à retrouver la déformation mesurée expérimentalement. Comparez à la valeur donnée par le calcul d’élasticité plane.
*===========================================================
* options
*===========================================================
*
OPTI 'ECHO' 1;
OPTI 'DIME' 2; 
OPTI 'MODE' PLAN DEFO;
OPTI 'ELEM' QUA8;
OPTI 'TRAC' OPEN;
*
*===========================================================
* paramètres
*===========================================================
*
* dimensions
lx = 0.1;
*
* matériau
young  = 0.2E6 ;
nu     = 0.15 ;
*
* chargement
appp   = 1.E5 ;
*
* finesse du maillage
N = 20;
*
*===========================================================
* geometrie + maillage (dimensions en metres)
*===========================================================
*
* points
P1 = lx   0.0;
P2 = lx   lx;
P3 = 0.0  0.0;
P4 = 0.0  lx;
PC = (lx/2.0) (lx/2.0);
*
* droites
D1 = P1 D N P2 ;
D2 = P2 D N P4 ;
D3 = P4 D N P3 ;
D4 = P3 D N P1 ;
*
* maillage
SURF1 = DALL D1 D2 D3 D4 'PLAN';
* 
* statistiques                                                              
ELSURF1 = NBEL SURF1;
NOSURF1 = NBNO SURF1;        
*
*===========================================================
* loi de comportement
*===========================================================
*
MO = MODE SURF1 MECANIQUE ELASTIQUE QUA8;
MA = MATE MO 'YOUN' young 'NU' nu;
RI1 = RIGI MO MA;
*
*===========================================================
* conditions aux limites en déplacement
*===========================================================
*
* encastrement
B1 = BLOQ DEPL D4;
RI = RI1 ET B1;
*
*===========================================================
* conditions aux limites en force
*===========================================================
*
* pression imposée
F = PRES 'MASS' MO appp D2; 
*
*===========================================================
* resolution : champs de deplacement 
*===========================================================
*
* calcul du déplacement
DEP = RESO RI F;
*
* affichage de la déformée
DEF0 = DEFO SURF1 DEP  0. 'BLEU' ;
DEF1 = DEFO SURF1 DEP  3. 'ROUG' ;
TITR 'DEFORMEE DE LA STRUCTURE';
TRAC QUAL (DEF0 ET DEF1);
*
* affichage des composantes
U1 = EXCO UX DEP;
TITR 'COMPOSANTE X DU DEPLACEMENT';
TRAC QUAL U1 SURF1;
*
U2 = EXCO UY DEP;
TITR 'COMPOSANTE Y DU DEPLACEMENT';
TRAC QUAL U2 SURF1;
*
*===========================================================
* resolution : contraintes
*===========================================================
*
* champ de contraintes
SIG = SIGM MO MA DEP;
* 
* tracé de sigma_zz
SZZ = EXCO SMZZ SIG;
TITR 'COMPOSANTE ZZ DE LA CONTRAINTE';
TRAC QUAL SZZ MO SURF1;
*
*===========================================================
* resolution : déformation
*===========================================================
*
* calcul de la déformation
EPS = EPSI MO DEP;
*
* obtention de la déformation yy au centre (PROC = point le plus proche)
PEXTR = POINT SURF1 PROC ((lx*0.5) (lx*0.5));
CHAM1 = CHAN NOEUD MO EPS;
CHPO1 = CHAN CHPO  MO CHAM1;
EPS22 = EXTR CHPO1 EPYY PEXTR;
*
*==========================================================
* affichage des resultats
*==========================================================
*
SAUT 2 LIGN;
MESS ' RESULTAT ';
MESS '---------------------------';
SAUT 1 LIGN;
MESS ' Deformation yy au centre :' EPS22;
*      
SAUT 2 LIGN;
MESS ' PROPRIETES DU CALCUL ';
MESS '---------------------------';                                                                         
MESS '    Nombre d elements :' ELSURF1;
MESS '    Nombre de noeuds  :' NOSURF1;
MESS '    Nombre de d.d.l.  :' (NOSURF1 * 3);
SAUT 1 LIGN;
*
*==================================================================  
* temps de calcul                         
*==================================================================           
*                                                                               
SAUT 1 LIGN;
TEMPS;
SAUT 1 LIGN;
*
*==================================================================  
* fin                    
*==================================================================           
*                                                                                 
FIN;

7.5 Crédits

La conception des montages a été réalisée par Michel Coret et Jean-Michel Lebrun (Laboratoire GeM, Nantes).